.key IFACE/K,DEBUG/S
.bra {
.ket }
;
.def IFACE ether0
;
; AmiTCP/IP startnet script
;
; Copyright © 1996 AmiTCP/IP Group,
;                  NSDi - Network Solutions Development Inc., Finland
;                  All rights reserved.
;
; *NOTE*  YOU SHOULD NOT NEED TO EDIT ANYTHING BELOW. IF YOU NEED TO START
; *NOTE*  UTILITIES, DO IT IN THE AmiTCP:db/User-Startnet.
; *NOTE*  YOU CAN STOP THESE UTILITIES IN AmiTCP:db/User-Stopnet.
;
; Set the failat level so that the errors can be handled by the script
FailAt 21

Version bsdsocket.library >nil:
If NOT Warn
  Echo AmiTCP/IP is already running
  Echo Exiting...
  Quit 20
EndIf

Cpu Check 68020 >nil:
If NOT Warn
  If Exists AmiTCP:AmiTCP.020
    If X EQ "X{DEBUG}"
      Run >nil: <nil: AmiTCP:AmiTCP.020 {DEBUG}
    Else
      Run AmiTCP:AmiTCP.020 {DEBUG}
    EndIf
    Skip started
  EndIf
EndIf
If X EQ "X{DEBUG}"
  Run >nil: <nil: AmiTCP:AmiTCP {DEBUG}
Else
  Run AmiTCP:AmiTCP {DEBUG}
EndIf
Lab started
; Wait max 10 seconds
WaitForPort AMITCP
If NOT Warn
  ; Log in with the default user name (ENV:LOGNAME)
  AmiTCP:bin/login -f

  If X EQ "X{DEBUG}"
    Run >nil: <nil: AmiTCP:bin/dhcpconfig {IFACE}
  Else
    Run AmiTCP:bin/dhcpconfig {IFACE}
  EndIf
  ; Wait max 10 seconds
  WaitForPort DHCPCONFIG
  If Warn
    Echo Interface configuration in progress...
  Else
    Echo Interface configured.
  EndIf
  ;
  ; Mount TCP:
  ;
  Assign TCP: Exists >NIL:
  IF Warn
    Mount TCP: from AmiTCP:devs/Inet-Mountlist
  EndIf
  ;
  ; Start utilities in AmiTCP:db/User-Startnet
  ;
  If Exists AmiTCP:db/User-Startnet
    Execute AmiTCP:db/User-Startnet
  EndIf
Else
  Echo AmiTCP/IP couldn't be started!
EndIf

; EOF